Programmieren unter dem Betriebssystem FutureOS in Assembler für Anfänger, Fortgeschrittene und Profis

Voraussetzungen um ein Assembler Programm für FutureOS zu erstellen
· Ein CPC6128 mit Grünmonitor (empfohlen) oder Farbmonitor ist vorhanden.
· Das Betriebssystem FutureOS (System-Version .8 oder höher) ist in einer EPROM-Karte, dem MegaFlash, der ROM-RAM-Box, dem SYMBiFACE II oder einer ähnlichen Karte installiert. 
FutureOS kann unter http://www.FutureOS.de heruntergeladen werden.
· Ein Assembler steht zur Verfügung. Die Beispiele in diesem Handbuch beziehen sich auf den MAXAM Assembler im ROM, können aber auf jeden Assembler übertragen werden, der in der Lage ist Binär-Dateien (*.BIN) zu schreiben.
Das ROM des MAXAM Assemblers kann unter ftp://ftp.nvg.ntnu.no/pub/cpc/emulator/rom/ heruntergeladen werden.
· Grundlegende Kenntnisse über Maschinensprache (Z80) sollten vorhanden sein.
Anmerkungen: Anstatt des MAXAM 1.14 Assembler ROMs können auch zwei ROMs mit Protext und MAXAM 1½ installiert werden, hierbei dient Protext als Texteditor.
Die Einschaltmeldung des CPCs bzw. des CPC Emulators sollte in etwa so aussehen:

Sollte kein echter CPC6128 zur Verfügung stehen, so kann auch ein CPC Emulator verwendet werden, Beispiele wären Caprice, JavaCPC, WinApe, WinCPC etc.

Vorbereitungen zum Schreiben eines Programms
Sie benötigen eine Diskette mit der Datei “#E.D“. Diese Datei enthält alle EQUates, also alle Address-Zuweisungen für System-Variablen und System-Funktionen des Applikations-Programm-Interface (API).
Wenn sie auf Variablen des Systems zugreifen wollen, oder Funktionen des Betriebssystems aufrufen wollen, dann benötigen Sie deren Adresse im Speicher. Und genau diese Adressen sind in der Datei “#E.D“ angegeben. Ein DSK Image welches diese Datei enthält kann hier heruntergeladen werden:
http://www.colorado-boys-muenchen.de/users/futureos/files/Variable_Definitions_and_EQUates.zip
Sollen Variablen des Betriebssystems (hier: FutureOS) oder Bezeichnungen von Funktionsaufrufen (sogenannte Labels) verwendet werden, so ist am Anfang der Zeile das Semikolon zu entfernen.
Es gibt drei Möglichkeiten um mit der Variablen- und Funktions-Definitionsdatei “#E.D“ zu arbeiten:
· Die gesamte Datei “#E.D“ wird in den Quellcode des Programms integriert. Das Semikolon am Zeilenanfang wird bei allen benötigten Variablen und Funktionsaufrufen gelöscht.
· Die Datei “#E.D“ wird mittels der Anweisung: READ“#E.D“ vom Quellcode des Programms eingelesen. Dabei wird das Semikolon am Zeilenanfang bei allen benötigten Variablen und Funktionsaufrufen gelöscht. 
(Mittels des Befehls READ“Datei“ ist es dem MAXAM Assembler möglich zusätzliche Dateien an dieser Stelle in den Source-Code einzulesen und zu integrieren. READ kann aber nur im Hauptprogramm verwendet werden, eine Verschachtelung ist nicht möglich.)
· Die vom Programm / Quellcode benötigten Variablen-Bezeichnungen und die Namen der Funktionsaufrufe werden aus der Datei “#E.D“ in den Quellcode kopiert. Das Semikolon am Anfang einer jeden Zeile wird entfernt.
Mein erstes Programm „Hallo Welt“
Den Quell-Code eingeben
Um den Quell-Code eines Programms einzugeben ist folgendes zu tun:
1. Bei Verwendung von MAXAM 1.14
a. Schalten Sie den CPC ein (MAXAM und FutureOS vorhanden)
b. Legen Sie eine leere Diskette ins Laufwerk ein
c. Springen Sie in den MAXAM Assembler durch Eingabe des Kommandos |m,2
(dabei schaltet der Parameter „2“ nach dem Komma in den Bildschirm MODE 2).
d. Sie befinden sich nun im Monitor-Teil des MAXAM Assemblers, bitte geben Sie nun den Buchstaben „T“ gefolgt von Return ein, um in den Text-Editor zu gelangen.
e. Nun befinden Sie sich im Menu des Text-Editors. Bitte geben Sie „E“ ein, um Text eingeben zu können.
f. Im Text-Editor angelangt können Sie nun den Quell-Code eines jeden Programms eingeben.
g. >> Jetzt bitte den Quell-Code eingeben << Nach Eingabe des Quell-Codes kann der Editor durch drücken der ESC Taste verlassen werden.
h. Mit „S“ können Sie nun ihren Quell-Code auf Diskette abspeichern.
2. Bei Verwendung von MAXAM 1½ und Protext
a. Schalten Sie den CPC ein (MAXAM 1½, Protext und FutureOS vorhanden)
b. Legen Sie eine leere Diskette ins Laufwerk ein
c. Springen Sie in den Protext Text-Editor durch Eingabe des Kommandos |p.
d. Sie befinden sich nun im Befehls-Modus von Protext, bitte geben Sie nun den Befehl „prog“ gefolgt von Return ein, um den Text-Editor auf Quell-Code einzustellen.
e. Nun blinkt der Cursor im Text-Editor. Hier können Sie nun den Quell-Code ihres Programms eingeben.
f. >> Jetzt bitte den Quell-Code eingeben << Nach Eingabe des Quell-Codes kann der Editor durch drücken der ESC Taste verlassen werden.
g. Durch Eingabe des Befehls „s“ und eines gültigen Dateinamens können Sie nun ihren Quell-Code auf Diskette abspeichern.
Anmerkung: Alle mit / für MAXAM erstellten Quell-Codes sollten immer die Datei-Erweiterung „.MAX“ enthalten. So lässt sich leicht erkennen, dass es sich um Quell-Code für MAXAM handelt.

Nun wollen wie gleich ein einfach „Hallo Welt“ Programm eingeben, dass einfach nur „Hallo Welt“ auf den Bildschirm schreibt. Den Quell-Code finden Sie auf den nächsten Seite. Bitte geben Sie den Quell-Code in den Assembler bzw. mit Protext ein, und vergessen Sie nicht den Quell-Code auf Diskette unter dem Namen „hello.max“ abzuspeichern. (Falls Sie mit diesem Handbuch eine Diskette erhalten haben, so befindet sich der Quell-Code bereits fertig eingetippt auf der Diskette, sein Name ist „HELLO.MAX“).


;Hello World – Name dieser Datei HELLO.MAX
;
;Dieses Programm schreibt "Hello World" in den unteren Bereich des FutureOS
;Desktop. Dabei werden die Icons nicht verändert.

ORG &8000 	;Der Befehl ORG legt die Adresse fest, ab welcher der
;assemblierte Maschinen-Code im Speicher abgelegt werden soll.
;In diesem Fall wird der Maschinen-Code ab &8000 abgelegt.

WRITE"HW.64K" 	;Der Befehl WRITE schreibt den generierten Maschinen-Code
;auf Diskette. Dabei wird der Dateinamen “HW.64K”
;verwendet.
;Die Erweiterung „.64K“ zeigt an, dass das assemblierte
;Programm im Hauptspeicher ausgeführt wird.
;Das assemblierte Binär-Programm „HW.64K“ bekommt vom
;Assembler automatisch eine Autostart-Adresse zugewiesen.
;Die Autostart-Adresse entspricht hierbei der Adresse,
;ab dem der Code abgelegt wird, siehe ORG Befehl.
;In diesem Falle ist das wiederum &8000.
;Ein so abgespeichertes Programm kann deshalb direkt
;unter FutureOS gestartet werden.
;
;Ohne den Befehl WRITE würde der assemblierte Code direkt
;im Speicher abgelegt werden. In diesem Falle ab &8000.

;Ab hier beginnt der eigentliche Programm-Code

HELLO LD  BC,(&FF01) 	;Das Doppelregister BC wird aus der Adresse &FF01
;geladen. Diese 16 Bit Adresse enthält die Nummer
;von ROM A des FutureOS (in unteren Byte) und den 
;Wert &DF (im oberen Byte).
;Über den Port &DFxx wird im CPC das obere ROM
;ausgewählt. Normalerweise liegt ROM A des
;FutureOS auf ROM-Auswahl 10 (&0A in hexadezimal)
;In diesem Fall enthält BC den Wert &DF0A

OUT (C),C 		;Dieser Befehl sendet den Wert des Registers C
;an die durch BC adressierte Ausgabe-Schnittstelle.
;Also wird &0A an den Port &DF0A gesendet.
;&DFxx ist für die obere ROM Auswahl zuständig.
;Es wird also FutureOS ROM A eingeblendet.
;Dieses obere ROM liegt zwischen &C000 und &FFFF.
;
;Das FutureOS ROM A wurde ausgewählt, um darin
;enthaltene Funktionen ausführen zu können.

LD  BC,&7F82     	;Die Ausgabeschnittstelle &7Fxx ist für die Auswahl
;von RAM, ROM und des Bildschirm-MODEs zuständig.
;Der Wert &82 bewirkt dabei folgendes;
;- Das obere ROM wird eingeblendet, anstatt RAM
;  (Damit wird das FutureOS ROM A eingeblendet
;  Funktionen in OS ROM können so benutzt werden)
;- Das untere ROM wird zwischen &0000 und &3FFF
;  eingeblendet. (Und damit wird auch der normale
;  Zeichensatz des CPC von &3800 bis &3FFF
;  eingeblendet. Das ist nötig, da sich im RAM
;  bisher noch kein Zeichensatz befindet)
;- Der Bildschirm-Mode wird auf 2 belassen
;  (MODE 2 war auch zuvor schon eingeblendet)
OUT (C),C        	;Wert &82 an Port &7Fxx senden, damit ROMs ein.



LD  (RAMCHAR),BC 	;Der aktuelle MODE und der Status des oberen und
;des unteren ROMs wird in die RAM Variable
;RAMCHAR geschrieben.
;Dadurch weiss das OS über MODE um RAM Status
;bescheid.

			;Natürlich ließe sich das auch in Form einer OS
			;Funktion realisieren, das wäre aber deutlich
			;umständlicher, und vor allem langsamer, als die
			;Verwendung von drei Z80 Befehlen

;Bisher wurde das FutureOS ROM A ab &C000 eingeblendet. Und es wurde
;das untere ROM mit dem darin enthaltenen Zeichensatz einbeblendet.

LD   HL,TXT 	;Das Doppelregister HL wird mit der Adresse des
;auszugebenden Textes geladen. Diese 16 Bit Adresse
;wird auch als Zeiger, Vektor oder Pointer etc.
;bezeichnet, da sie auf ein LABEL (eine Marke)
;im RAM des CPC zeigt.

CALL TERM_2 	;FutureOS stellt mehrere OS-Funktionen zur Ausgabe
;von Text auf dem Bildschirm zur Verfügung.
;Mit TERM_2 können normale Zeichen im MODE 2
;ausgegeben werden.
;Beim Aufruf vom TERM_2 muss das Doppelregister HL
;mit einer Adresse geladen sein, die auf den Text
;zeigt, der dargestellt werden soll.

;Der Text "Hello World!" wurde nun auf dem Bildschirm ausgegeben!

;Am Ende des Programms muss das Programm die Kontrolle wieder an das OS
;zurückgeben. Dies geschieht z.B. auf folgende Weise..

LD   HL,KLICK 	;Die OS Funktion KLICK ist ein Einsprung ins OS.
;Sie wird nur dann verwendet, wenn das ausführende
;Programm die Icons in der oberen Haelfte des
;Desktop nicht verändert hat.
;In unserem Falle hat das Programm lediglich im
;unteren Bereich des Bildschirms Text ausgegeben.
;Die Systemfunktion KLICK kann also verwendet
;werden.
;Das sich KLICK aber im ROM D befindet, wir aber
;ROM A eingeblendet haben, kann KLICK nicht direkt
;aufgerufen werden. Stattdessen wird das Doppelreg.
;HL mit der Adresse von KLICK geladen. Und...

JP   ROM_D    	;Die Systemfunktion ROM_D ist in allen vier ROMs
;des FutureOS vorhanden, sie kann also immer
;aufgerufen werden.
;Das Programm springt hier direkt zu ROM_D.
;Die Systemfunktion ROM_D blendet das FutureOS
;ROM D ein und springt anschließend an die Adresse,
;die in HL angegeben ist. In diesem Beispiel ist
;das die Adresse der Systemfunktion	KLICK.

;Anstelle der letzten beiden Befehle wäre es auch möglich zuerst FutureOS
;ROM D einzublenden und dann direkt zu KLICK zu springen.
;
;Das würde dann so aussehen:
;LD  BC,(&FF13) ;Schnittstelle ROM-select und Nummer von ROM D in BC laden
;OUT (C),C      ;FutureOS ROM D auswählen
;JP  KLICK      ;Zurück ins OS springen


;Auszugebender Text ab dem LABEL TXT
;Der auszugebende Text besteht aus einem Steuerzeichen (drei Bytes),
;die den Cursor auf dem Bildschirm positionieren, und aus dem Text
;“Hello World“.

TXT 	DB &1E,21,26 	;Der Text beginnt mit einem Steuerzeichen, also mit
;einem sogenannten Control Code.
;Der Control Code &1E arbeitet ähnlich wie der
;BASIC Befehl LOCATE, er positioniert den Cursor
;auf dem Bildschirm. Dabei wird vorausgesetzt, dass
;sich der Bildschirm im 64 x 32 Modus befindet.
;Das bedeutet 64 Zeichen pro Zeile, und 32 Zeilen.
;Beim Aufruf eines Programms befindet sich der
;Bildschirm bereits in diesem Mode, er muss also
;nicht extra eingestellt werden.
;Dem Control Code &1E (LOCATE) folgen zwei Bytes,
;die die Y und X Position angeben, auf die der
;Cursor gesetzt werden soll.
;Die Y-Position ist hierbei die 21. Zeile.
;Und X-Position ist die 26. Spalte.

DB "Hello World!" ;Dies ist der auszugebende Text

DB 0			;Der Text wird durch ein Null-Byte beendet.
;Neben Control-Code &00 kann auch der Control-Code
;&1A als String-Terminator verwendet werden

;Die Steuerzeichen des FutureOS sind mit ausführlicher Beschreibung im
;großen Handbuch zu finden.


;Nachfolgend werden die LABELs der System-Variablen und System-Funktionen
;aufgelistet.
;Diese EQUates sind direkt von der Datei “#E.D“ übernommen.

;EQUates of OS variables

RAMCHAR EQU &B847 ;located in first 64 KB RAM


;EQUates of System Calls

TERM_2 EQU &D48C 	;located in ROM A (Textausgabe)
KLICK  EQU &FE9A 	;located in ROM D (Rücksprung in den Desktop)
ROM_D  EQU &FF12 	;located in all ROMs 


Den Quellcode abspeichern
In jeden Fall sollte der frisch eingegebene oder veränderte Quellcode sofort auf Diskette abgespeichert werden. Es empfiehlt sich hierbei auf mehrere Disketten zu speichern, die an verschiedenen Orten aufbewahrt werden.
Bei der Verwendung eines Emulators sollten die generierten DSK Images auf verschiedenen Festplatten gesichert werden. Es empfiehlt sich auch regelmäßig Sicherheitskopien auf CD bzw. USB Massenspeicher zu ziehen.


Das Assemblieren des Programms
Nach der Eingabe bzw. dem Bearbeitern des Quell-Codes – und nachdem Sie ihn auf Diskette gesichert haben – kann der Quell-Code nun assembliert werden. Assemblieren bedeutet, dass der Assembler den Quell-Code in ein Binär-Programm übersetzt, so ein Binär-Programm kann vom Z80 Prozessor direkt ausgeführt werden.
Das Assemblieren eines Programms wird folgendermaßen durchgeführt:
1. Bei Verwendung von MAXAM 1.14
a. Der Quell-Code wurde entweder gerade unter MAXAM eingegeben, oder im Text-Editor von MAXAM mittels des Kommandos „L“ von Diskette geladen.
b. Legen Sie nun bitte die Diskette ins Laufwerk, auf die das fertige Programm abgespeichert werden soll.
c. Im Text-Editor des MAXAM Assemblers geben Sie nun den Befehl „A“ ein, gefolgt von Return. MAXAM beginnt nun zu assemblieren.
d. Nach dem Ende der Assemblierung drücken Sie bitte eine Taste um ins Text-Editor Menu von MAXAM zurückzukehren.
e. Das generierte Binär-Programm befindet sich nun auf Diskette
f. Bei diesem Beispiel trägt es den Datei-Namen „HW.64K“
2. Bei Verwendung von MAXAM 1½ und Protext
a. Der Quell-Code wurde entweder gerade unter Prowort eingegeben, oder im Befehls-Modus von Prowort mittels des Kommandos „L“ von Diskette geladen.
b. Legen Sie nun bitte die Diskette ins Laufwerk, auf die das fertige Programm abgespeichert werden soll.
c. Im Befehls-Modus von Prowort geben Sie nun den Befehl „asm“ ein, gefolgt von Return. Dadurch wird der MAXAM Assembler aufgerufen und beginnt nun zu assemblieren.
d. Nach dem Ende der Assemblierung drücken Sie bitte eine Taste um in den Befehls-Modus von Prowort zurückzukehren.
e. Das generierte Binär-Programm befindet sich nun auf Diskette
f. Bei diesem Beispiel trägt es den Datei-Namen „HW.64K“
Anmerkung: Um das Inhaltsverzeichnis der eingelegten Diskette anzuzeigen können Sie unter MAXAM mit „X“ in den RSX Modus wechseln, dort geben sie „cat“ ein, wie gewohnt. Das Inhaltsverzeichnis der Diskette wird nun angezeigt. Drücken Sie anschließend ESC um ins vorige Menu zurückzukehren. Unter Prowort geben Sie einfach „cat“ im Befehls-Modus ein um das Inhaltsverzeichnis der gerade eingelegten Diskette anzuzeigen.


Ausführen eines Programms unter FutureOS
Bisher haben Sie den Quell-Code eines Programms in den Text-Editor eingegeben, Sie haben den Quell-Code auf Diskette gespeichert und anschließend haben Sie bereits den Quell-Code assembliert. Das assemblierte Binär-Programm befindet sich auf Diskette, und nun wollen wir es unter FutureOS starten.
Starten eines Programms unter FutureOS
· Den CPC6128 oder 6128 Plus einschalten. FutureOS zeigt seine Initialisierungs-Meldung
· Mit dem Befehl „|OS“ das Betriebssystem FutureOS booten
· Die Diskette mit dem zu startenden Programm in ein Laufwerk einlegen
· Das entsprechende Laufwerks-Icon anklicken. Dabei symbolisiert das Icon „A“ das interne 3“ Laufwerk des CPC, und das Icon „B“ symbolisiert das am Disc-Drive-B Anschuss befindliche Laufwerk (egal ob 3“, 3.5“ oder 5.25“)
· Nun klicken Sie bitte das „DIR“ Icon an. Nach dem Anklicken sehen Sie im unteren Teil des Bildschirms das Inhaltsverzeichnis des gewählten Laufwerks
· Anmerkung: Sollten Sie mehrere Laufwerke markiert haben, oder sollte die Diskette mehr als 64 Dateien beinhalten, so lässt sich mittels der Tasten „Control“ und „Shift“ durch das Inhaltsverzeichnis blättern
· In dem angezeigten Inhaltsverzeichnis klicken Sie nun bitte das zu startende Programm an
· Anschießend klicken Sie das „RUN“ Icon an
· Nun wird das Programm geladen und ausgeführt
· Nach dem Ende des Programms können Sie FutureOS mittels des „END“ Icons verlassen

