CPC Wiki Forum Die Amstrad-CPC-Community

TicTacToe für FutureOS

Iniciado por SRS · 17/11/2026 21:32 · Respuestas: 2 · Visitas: 45
#1
Lange lange habe ich den Zugang zur Entwicklung für Future-OS nicht geschnallt.

Künstliche Intelligenz hat beim Studium der Anleitung und ersten Fehlern geholfen.

Und - tadaa - Textbasiertes TicTacToe mit Computergegner für FOS.

Auch wenn es für mich nur um "ich schaffe das" ging, möchte ich es mit euch teilen.
Editado por última vez por SRS el Ayer, 14:42
tictactoe_fos.png
👍 1👎 0+1
TFM
#2
Sehr schön 🙂 🙂 🙂

Würdest Du auch den Source mit uns teilen?
TFM of FutureSoft
http://www.FutureOS.de --> Das Betriebssystem FutureOS (Update: 07.10.2026)
Editado por última vez por TFM el Ayer, 19:42
👍 0👎 0
#3
Aber gerne. Nicht schick, aber funktioniert.

ORG &9000

ROM_A_SEL   EQU &FF01
ROM_C_SEL   EQU &FF0D
ROM_D_SEL   EQU &FF13

H_ALLET     EQU &C02F
WART_TS     EQU &C4DB
LESC        EQU &C017
S64X32      EQU &D5A8
TUR_E       EQU &FE9D


START:
    LD BC,&7F82
    OUT (C),C

    LD BC,(ROM_A_SEL)
    OUT (C),C
    CALL S64X32

    LD HL,FELD
    LD B,9
    LD A,'1'
INITLP:
    LD (HL),A
    INC HL
    INC A
    DJNZ INITLP

    LD A,'X'
    LD (SPIELER),A
    XOR A
    LD (ZUEGE),A

RUNDE:
    CALL CLSFELD

    LD HL,TXTTIT
    LD DE,&C000
    CALL DRSTR

    LD A,(SPIELER)
    CP 'O'
    JR Z,KIZUG

    LD HL,TXTZUG
    LD DE,&C280
    CALL DRSTR

    LD BC,(ROM_A_SEL)
    OUT (C),C
    CALL WART_TS

EINGLP:
    CALL H_ALLET
    INC A
    JR Z,EINGLP
    DEC A

    CP &FC
    JP Z,ENDEOS
    CP 3
    JR Z,ENDEOS
    CP 27
    JR Z,ENDEOS

    SUB '1'
    JR C,EINGLP
    CP 9
    JR NC,EINGLP

    LD E,A
    LD D,0
    LD HL,FELD
    ADD HL,DE

    LD A,(HL)
    CP 'A'
    JR NC,EINGLP

    LD (HL),'X'
    JR NACHZUG

KIZUG:
    LD HL,TXTKI
    LD DE,&C280
    CALL DRSTR
    CALL KIWAHL

NACHZUG:
    LD HL,ZUEGE
    INC (HL)

    CALL PRFSIEG
    JR C,GEWONNEN

    LD A,(ZUEGE)
    CP 9
    JR Z,REMIS

    LD A,(SPIELER)
    XOR &17
    LD (SPIELER),A
    JR RUNDE

GEWONNEN:
    CALL CLSFELD
    LD A,(SPIELER)
    CP 'O'
    LD HL,TXTSIEG
    JR NZ,DRENDE
    LD HL,TXTKISG
    JR DRENDE

REMIS:
    CALL CLSFELD
    LD HL,TXTREM

DRENDE:
    LD DE,&C280
    CALL DRSTR
    LD HL,TXTNEU
    CALL DRSTR

    LD BC,(ROM_A_SEL)
    OUT (C),C
    CALL WART_TS

WARTJN:
    CALL H_ALLET
    INC A
    JR Z,WARTJN
    DEC A

    AND &DF
    CP 'J'
    JP Z,START

ENDEOS:
    LD BC,(ROM_D_SEL)
    OUT (C),C
    JP TUR_E

CLSFELD:
    LD BC,(ROM_C_SEL)
    OUT (C),C
    CALL LESC

ZGFELD:
    LD HL,FELD
    LD DE,&C0C2
    LD B,3
ZEILLP:
    PUSH BC
    PUSH DE
    LD B,3
SPALTLP:
    LD A,(HL)
    INC HL
    CALL DRZEICH
    INC DE
    DJNZ TRENN
    JR ZEILEND
TRENN:
    LD A,'|'
    CALL DRZEICH
    INC DE
    JR SPALTLP

ZEILEND:
    POP DE
    CALL ADDDE64
    POP BC
    DEC B
    RET Z

    PUSH BC
    PUSH HL
    PUSH DE
    LD HL,TXTTRN
    CALL DRSTR
    POP DE
    CALL ADDDE64
    POP HL
    POP BC
    JR ZEILLP

ADDDE64:
    LD A,E
    ADD A,64
    LD E,A
    RET NC
    INC D
    RET

DRSTR:
    LD A,(HL)
    OR A
    RET Z
    INC HL
    CALL DRZEICH
    INC DE
    JR DRSTR

DRZEICH:
    PUSH HL
    PUSH DE
    PUSH BC
    LD L,A
    LD H,0
    ADD HL,HL
    ADD HL,HL
    ADD HL,HL
    LD BC,&3800
    ADD HL,BC

    LD BC,&7F82
    OUT (C),C

    LD B,8
ZCHNLP:
    LD A,(HL)
    LD (DE),A
    INC HL
    LD A,D
    ADD A,8
    LD D,A
    DJNZ ZCHNLP
    POP BC
    POP DE
    POP HL
    RET

KIWAHL:
    LD C,'O'
    CALL SUCH2
    JR C,KISETZ

    LD C,'X'
    CALL SUCH2
    JR C,KISETZ

    LD IX,KIPRIO
    LD B,9
    LD D,0
PRIOLP:
    LD E,(IX+0)
    INC IX
    LD HL,FELD
    ADD HL,DE
    LD A,(HL)
    CP 'A'
    JR C,KISETZ
    DJNZ PRIOLP
    RET

KISETZ:
    LD HL,FELD
    ADD HL,DE
    LD (HL),'O'
    RET

PRFSIEG:
    LD A,(SPIELER)
    LD C,A
    LD A,3
    JR SUCHLIN

SUCH2:
    LD A,2

SUCHLIN:
    LD (SOLLANZ),A
    LD IX,REIHEN
    LD B,8
    LD D,0
LINLP:
    PUSH BC
    LD B,0
    LD A,&FF
    LD (FREIIDX),A

    LD E,(IX+0)
    CALL PRFZELL
    LD E,(IX+1)
    CALL PRFZELL
    LD E,(IX+2)
    CALL PRFZELL

    LD A,(SOLLANZ)
    CP B
    POP BC
    JR NZ,NAECHST

    LD A,(SOLLANZ)
    CP 3
    JR Z,GEFUNDN

    LD A,(FREIIDX)
    CP &FF
    JR Z,NAECHST

GEFUNDN:
    LD E,A
    SCF
    RET

NAECHST:
    INC IX
    INC IX
    INC IX
    DJNZ LINLP
    OR A
    RET

PRFZELL:
    LD HL,FELD
    ADD HL,DE
    LD A,(HL)
    CP C
    JR NZ,KEINSYM
    INC B
    RET
KEINSYM:
    CP 'A'
    RET NC
    LD A,E
    LD (FREIIDX),A
    RET

KIPRIO:
    DEFB 4,0,2,6,8,1,3,5,7

REIHEN:
    DEFB 0,1,2, 3,4,5, 6,7,8
    DEFB 0,3,6, 1,4,7, 2,5,8
    DEFB 0,4,8, 2,4,6

TXTTIT:
    DEFB "=== TIC TAC TOE vs. CPC (FutureOS) ===",0
TXTTRN:
    DEFB "-+-+-",0
TXTZUG:
    DEFB "Dein Zug (1-9, ESC=Desktop) - ",0
TXTKI:
    DEFB "CPC zieht...",0
TXTSIEG:
    DEFB "Gewonnen! ",0
TXTKISG:
    DEFB "Der CPC hat gewonnen! ",0
TXTREM:
    DEFB "Unentschieden! ",0
TXTNEU:
    DEFB "Nochmal (J/N)?",0

SPIELER:     DEFS 1
ZUEGE:       DEFS 1
SOLLANZ:     DEFS 1
FREIIDX:     DEFS 1
FELD:        DEFS 9
👍 0👎 0

Entra para escribir